home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
C64
/
T-TPUG Old Monthly Disks
/
(c)tt.d64
/
kat $ mouse.c
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2007-02-04
|
2KB
|
58 lines
1 GOSUB1000
10 INPUT"[147]SKILL LEVEL (1-10)";S
20 INPUT"USE JOYSTICK Y [157][157][157][157][157]";A$
22 IFA$="Y"THEND=1:GOTO30
23 D=2
30 PRINT"SETTING UP MAZE"
100 DIMA(3):A(0)=2:A(1)=-80:A(2)=-2:A(3)=80:WL=160:HL=32:SC=35000:A=SC+41
110 FORT=0TO24:FORR=0TO38:POKESC+R+40*T,160:NEXT:NEXT
120 POKEA,4
130 J=INT(RND(1)*4):X=J
140 B=A+A(J):IFPEEK(B)=WLTHENPOKEB,J:POKEA+A(J)/2,HL:A=B:GOTO130
150 J=(J+1)*-(J<3):IFJ<>XTHEN140
160 J=PEEK(A):POKEA,HL::IFJ<4THENA=A-A(J):GOTO130
170 FORT=0TO999:POKE1024+T,PEEK(35000+T):NEXT
201 M(0)=0:M(1)=-40:M(2)=40:M(4)=-1:M(8)=1:A=1065:POKEA,81:B=2024-40-3:TM=TI
202 POKEB,1:J=2:POKE2021,6
210 ONDGOTO215,330
215 JV=255-PEEK(56321)
216 IF((255-JV)AND16)=0THENGOSUB600:GOTO260
220 IFJV<10ANDJV>0THEN231
230 GOTO260
231 IFPEEK(A+M(JV))=6THEN300
232 IFPEEK(A+M(JV))=1THEN400
240 IFPEEK(A+M(JV))<>32THEN260
250 POKEA+M(JV),81:POKEA,32:A=A+M(JV)
260 FORT=1TOS:C=B+A(J)/2
263 IFPEEK(C)=81THEN400
265 IFPEEK(C)=HLTHENPOKEC,11:POKEB,HL:B=C:J=(J+2)+4*(J>1)
270 J=(J-1)-4*(J=0):NEXT:GOTO210
300 TM=INT((TI-TM)/60)
301 PRINT"[147]YOU WON IN"TM"SECONDS":GOTO490
330 JV=PEEK(203)
340 IFJV=64THEN260
350 JV=-1*(JV=9)-4*(JV=10)-2*(JV=12)-8*(JV=13)-5*(JV=60)
351 IFJV=5THENGOSUB600:GOTO260
395 GOTO231
400 PRINT"[147]YOU LOST !!"
490 FORT=1TO100:GETA$:NEXT
500 INPUT"ANOTHER GAME Y [157][157][157][157][157]";A$
510 IFA$="Y"THENRUN
599 END
600 POKEA,32
601 A=INT(RND(1)*920+1064):IFPEEK(A)<>32THEN601
610 POKEA,81
620 TM=TM-3600:RETURN
1000 PRINT"[147]"SPC(16)"KAT AND MOUSE"
1001 PRINT" BY: TODD VERSTRATEN"
1002 INPUT"WANT INSTRUCTIONS N [157][157][157][157][157]";A$
1003 IFA$="N"THENRETURN
1004 PRINT"MOVE THE [209] AROUND THE MAZE"
1005 PRINT"TO THE FINISH AVOIDING THE 'K'"
1006 PRINT"IN DESPARATION HIT THE PANIC"
1007 PRINT"BUTTON (BUTTON ON JOYSTICK)"
1008 PRINT"KEYBOARD CONTROLS ARE"
1009 PRINT" W[157][221][157][157][157]A[195][219][195]S[157][157][157][221][157]Z[157][157][157][157][157][157][157]SPACE BAR FOR PANIC"
1010 PRINT"HIT RETURN[146] TO CONT.":WAIT197,1:FORT=1TOPEEK(198):GETA$:NEXT
1011 RETURN